.版本 2
.DLL命令 GetCursorPos, 逻辑型, "user32.dll", "GetCursorPos"
  .参数 光标位置, POINT, 传址
.DLL命令 WindowFromPoint, 整数型, "user32.dll", "WindowFromPoint"
  .参数 X轴光标, 整数型
  .参数 Y轴光标, 整数型
.DLL命令 SendMessage, 整数型, , "SendMessageA"
  .参数 hwnd, 整数型
  .参数 wMsg, 整数型
  .参数 wParam, 整数型
  .参数 lParam, 文本型, 传址, any
.DLL命令 GetClassName, 整数型, "user32.dll", "GetClassNameA"
  .参数 句柄, 整数型
  .参数 文本, 文本型
  .参数 文本长度, 整数型
.DLL命令 GetClassLong, 整数型, , "GetClassLongA"
  .参数 句柄, 整数型
  .参数 信息, 整数型
.DLL命令 GetWindowLong, 整数型, "user32.dll", "GetWindowLongA"
  .参数 句柄, 整数型
  .参数 信息, 整数型
.DLL命令 GetWindowRect, 整数型, "user32.dll", "GetWindowRect"
  .参数 句柄, 整数型
  .参数 大小, RECT, 传址

.版本 2
.常量 WM_GETTEXT, "13"

.版本 2
.数据类型 POINT
  .成员 x, 整数型, , , X轴坐标
  .成员 y, 整数型, , , Y轴坐标
.数据类型 RECT
  .成员 Left, 整数型
  .成员 Top, 整数型
  .成员 Right, 整数型
  .成员 Bottom, 整数型
.数据类型 MSG
  .成员 hwnd, 整数型
  .成员 message, 整数型
  .成员 wParam, 整数型
  .成员 lParam, 整数型
  .成员 time, 整数型
  .成员 ptx, 整数型
  .成员 pty, 整数型

.版本 2
.程序集 窗口程序集1
.程序集变量 句柄, 整数型
.程序集变量 获取值, 整数型
.程序集变量 获取文本, 文本型
.子程序 _时钟1_周期事件
.局部变量 光标位置, POINT, 静态
.局部变量 窗口大小, RECT, 静态
GetCursorPos (光标位置)
获取值 ＝ WindowFromPoint (光标位置.x, 光标位置.y)
.如果真 (获取值 ≠ 句柄)
  句柄 ＝ 获取值
  窗口句柄.内容 ＝ “（&H” ＋ 取十六进制文本 (获取值) ＋ “）” ＋ 到文本 (获取值)
  获取文本 ＝ 取空白文本 (255)
  SendMessage (句柄, #WM_GETTEXT, 256, 获取文本)
  窗口标题.内容 ＝ 获取文本
  获取文本 ＝ 取空白文本 (255)
  GetClassName (句柄, 获取文本, 255)
  窗口类名.内容 ＝ 获取文本
  获取值 ＝ GetClassLong (句柄, -32)
  窗口类值.内容 ＝ “（&H” ＋ 取十六进制文本 (获取值) ＋ “）” ＋ 到文本 (获取值)
  获取值 ＝ GetWindowLong (句柄, -16)
  窗口风格.内容 ＝ “（&H” ＋ 取十六进制文本 (获取值) ＋ “）” ＋ 到文本 (获取值)
  获取值 ＝ GetWindowLong (句柄, -6)
  窗口扩展风格.内容 ＝ “（&H” ＋ 取十六进制文本 (获取值) ＋ “）” ＋ 到文本 (获取值)
  获取值 ＝ GetWindowLong (句柄, -12)
  窗口ID.内容 ＝ “（&H” ＋ 取十六进制文本 (获取值) ＋ “）” ＋ 到文本 (获取值)
  GetWindowRect (句柄, 窗口大小)
  窗口范围.内容 ＝ 到文本 (窗口大小.Left) ＋ “ ” ＋ 到文本 (窗口大小.Top) ＋ “ ” ＋ 到文本 (窗口大小.Right) ＋ “ ” ＋ 到文本 (窗口大小.Bottom)
.如果真结束