.版本 2
.子程序 开始截图, 逻辑型, 公开, 截图成功返回真，图片被自动保存到剪贴板。失败或放弃截图则返回假。
.参数 是否截取鼠标, 逻辑型, 可空
.参数 调节框颜色, 整数型, 可空, 默认：Red=10，Green=100，Blue=130 
.参数 矩形信息框颜色, 整数型, 可空, 默认黑色
.参数 矩形信息字体颜色, 整数型, 可空, 默认黑色
.子程序 取剪贴板位图, 字节集, 公开

.版本 2
.支持库 edroptarget
.支持库 shellEx
.支持库 eImgConverter
.支持库 iext
.支持库 EThread
.支持库 spec
.支持库 HtmlView
.程序集 窗口程序集_启动窗口
.程序集变量 request_id, 文本型
.程序集变量 压缩率, 整数型
.程序集变量 路径, 文本型
.程序集变量 a, 整数型
.子程序 __启动窗口_创建完毕
拖放对象1.注册拖放控件 (取窗口句柄 ())
a ＝ 注册热键 (取窗口句柄 (), 标签1.取窗口句柄 (), 0, #F4键)
文件_删除 (取运行目录 () ＋ “\123.jpg”)
压缩率 ＝ 滑块条1.位置
编辑框1.内容 ＝ 读配置项 (取运行目录 () ＋ “\表格配置.ini”, “配置”, “Token”, )
.子程序 _拖放对象1_得到文件
.参数 接收到的文件路径, 文本型
路径 ＝ 接收到的文件路径
转换到JPG (接收到的文件路径, 取运行目录 () ＋ “\123.jpg”, 假, 压缩率, 真, 0)
处理事件 ()
图片框1.图片 ＝ 读入文件 (取运行目录 () ＋ “\123.jpg”)
透明标签1.标题 ＝ 到文本 (取字节集长度 (图片框1.图片))
.子程序 _滑块条1_位置被改变
压缩率 ＝ 滑块条1.位置
转换到JPG (路径, 取运行目录 () ＋ “\123.jpg”, 假, 压缩率, 真, 0)
处理事件 ()
图片框1.图片 ＝ 读入文件 (取运行目录 () ＋ “\123.jpg”)
透明标签1.标题 ＝ 到文本 (取字节集长度 (图片框1.图片))
.子程序 _标签1_反馈事件, 整数型
.参数 参数一, 整数型
.参数 参数二, 整数型
.局部变量 jpg, 字节集
.如果真 (参数一 ＝ a)
  .如果真 (开始截图 ())
    滑块条1.禁止 ＝ 真
    路径 ＝ 取运行目录 () ＋ “\1234.jpg”
    写到文件 (路径, 剪辑板_取图片 (取窗口句柄 ()))
    处理事件 ()
    图片_转换 (读入文件 (取运行目录 () ＋ “\1234.jpg”), 2, 取运行目录 () ＋ “\123.jpg”, jpg)
    处理事件 ()
    图片框1.图片 ＝ 读入文件 (取运行目录 () ＋ “\123.jpg”)
    透明标签1.标题 ＝ 到文本 (取字节集长度 (图片框1.图片))
  .如果真结束
.如果真结束
.子程序 _按钮1_被单击
编辑框1.可视 ＝ 假
.如果真 (取字节集长度 (图片框1.图片) ＝ 0)
  _启动窗口.标题 ＝ “拖入图片再转换”
  返回 ()
.如果真结束
.如果真 (取字节集长度 (图片框1.图片) ＞ 150000)
  .如果真 (信息框 (“当前图片较大，转换时间较长”, 1, , _启动窗口) ＝ #取消钮)
    返回 ()
  .如果真结束
.如果真结束
按钮1.禁止 ＝ 真
滑块条1.禁止 ＝ 假
图片框2.可视 ＝ 真
_启动窗口.标题 ＝ “正在上传图片”
启动线程 (&上传图像, , )
.子程序 上传图像
.局部变量 地址, 文本型
.局部变量 数据, 文本型
.局部变量 图片, 文本型
.局部变量 Json, 类_json
.局部变量 str, 文本型
.局部变量 返回, 文本型
.局部变量 jpg, 字节集
图片框2.图片 ＝ 读入文件 (“C:\Users\wyz\Desktop\ICO\timg (1).gif”)
图片 ＝ 编码_URL编码 (编码_BASE64编码 (图片框1.图片), 真, 真)
地址 ＝ “https://aip.baidubce.com/rest/2.0/solution/v1/form_ocr/request?access_token=” ＋ 编辑框1.内容
数据 ＝ “image=” ＋ 图片 ＋ “&”
返回 ＝ 到文本 (网页_访问 (地址, 1, 数据))
.如果真 (寻找文本 (返回, “Access token expired”, , 假) ≠ -1)
  _启动窗口.标题 ＝ “访问令牌已过期”
  图片框2.可视 ＝ 假
  按钮1.禁止 ＝ 假
.如果真结束
.如果真 (寻找文本 (返回, “Access token invalid or no longer valid”, , 假) ≠ -1)
  _启动窗口.标题 ＝ “访问令牌无效或不再有效”
  图片框2.可视 ＝ 假
  按钮1.禁止 ＝ 假
.如果真结束
Json.解析 (返回)
str ＝ Json.取通用属性 (“result[0].request_id”, 真)
request_id ＝ 文本_替换 (str, , , , #引号, “”)
.如果真 (request_id ≠ “”)
  _启动窗口.标题 ＝ “正在处理，请稍等”
  启动线程 (&分析图像, , )
.如果真结束
.子程序 分析图像
.局部变量 地址1, 文本型
.局部变量 数据1, 文本型
.局部变量 选择, 文本型
.局部变量 返回1, 文本型
.局部变量 Json1, 类_json
.局部变量 str1, 文本型
地址1 ＝ “https://aip.baidubce.com/rest/2.0/solution/v1/form_ocr/get_request_result?access_token=” ＋ 编辑框1.内容
数据1 ＝ “request_id=” ＋ request_id ＋ “&result_type=excel&”
返回1 ＝ 到文本 (网页_访问 (地址1, 1, 数据1))
返回1 ＝ 编码_URL解码 (返回1, 真)
调试输出 (返回1)
.如果真 (寻找文本 (返回1, “未开始”, , 假) ≠ -1)
  程序_延时 (3000)
  启动线程 (&分析图像, , )
  返回 ()
.如果真结束
.如果真 (寻找文本 (返回1, “进行中”, , 假) ≠ -1)
  程序_延时 (3000)
  启动线程 (&分析图像, , )
  返回 ()
.如果真结束
.如果真 (寻找文本 (返回1, “image recognize error”, , 假) ≠ -1)
  _启动窗口.标题 ＝ “不属于表格图像”
  图片框2.可视 ＝ 假
  按钮1.禁止 ＝ 假
  返回 ()
.如果真结束
Json1.解析 (返回1)
str1 ＝ 文本_替换 (Json1.取通用属性 (“result.result_data”, 真), , , , #引号, “”)
_启动窗口.标题 ＝ “图像分析完成”
按钮1.禁止 ＝ 假
图片框2.可视 ＝ 假
超文本浏览框1.地址 ＝ str1
文件_删除 (取运行目录 () ＋ “\123.jpg”)
文件_删除 (取运行目录 () ＋ “\1234.jpg”)
.子程序 __启动窗口_被双击, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
编辑框1.可视 ＝ 真
.子程序 _图片框1_被双击, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.如果真 (取字节集长度 (图片框1.图片) ＝ 0)
  返回 ()
.如果真结束
载入 (窗口1, , 假)
.子程序 __启动窗口_将被销毁
文件_删除 (取运行目录 () ＋ “\123.jpg”)
文件_删除 (取运行目录 () ＋ “\1234.jpg”)
.子程序 _编辑框1_内容被改变
写配置项 (取运行目录 () ＋ “\表格配置.ini”, “配置”, “Token”, 编辑框1.内容)